//---------------------------------------------------------------------------------------------------------------------
// ORCHESTRA implementation of the 2SPNE SC/CE surface complexation model by Bradbury and Baeyens, as described in: 
//
// Sorption of Eu(III)/Cm(III) on Ca-montmorillonite and Na-illite. Part 2:Surface complexation modelling
// M. H. BRADBURY,1, B. BAEYENS, H. GECKEIS, and TH. RABUNG
// Geochimica et Cosmochimica Acta, Vol. 69, No. 23, pp. 5403–5412, 2005
//
// doi:10.1016/j.gca.2005.06.031
//
// Hans Meeussen, Joris Dijkstra January 2018
// www.meeussen.nl/orchestra/bradbury_baeyens.txt
//----------------------------------------------------------------------------------------------------------------------


//--------  The aqueous Eu species used: ---------------------- 
@species(Eu+3, 3)

@species(EuOH+2, 2)
@logKreaction(EuOH+2,    -7.2,  1.0, Eu+3, -1.0, H+,  1.0, H2O)

@species(Eu[OH]2+, 1)
@logKreaction(Eu[OH]2+, -15.1,  1.0, Eu+3, -2.0, H+,  2.0, H2O)

@species(Eu[OH]3, 0)
@logKreaction(Eu[OH]3,  -26.2,  1.0, Eu+3, -3.0, H+,  3.0, H2O)


//--------------------------------------------------------------


//--------  The adsorption model --------  
// First we define the the "BB_surface" class, which for this model is simply an ORCHESTRA phase.
// There are no electrostatic or other model equations involved in this model.
//--------------------------------------------------------------
@class: adsorptionmodelcode(BB_surface){
   @class: BB_surface(name, parent_phase ,concentration){
      @phase(<name>, <parent_phase>, <concentration>)
   }
}


//--------  Define a default "particle" phase, which can be changed in the GUI -------- 
@phase(part) 

//--------------------------------------------------------------
// define the components of the BB_montm model
//        modelname, parent particle, kg/kg, modeltype
@adsmodel(BB_montm,  part ,           1,      BB_surface)
//--------------------------------------------------------------

@class: adsorptionmodeltext(BB_montm){
//----------------------------------------------------------------------------------------
// This is an implementation of the (2SPNE SC/CE) two site protolysis non electrostatic surface complexation and cation
// exchange (2SPNE SC/CE) model according to:
// M. H. BRADBURY,1, B. BAEYENS, H. GECKEIS, and TH. RABUNG
// Geochimica et Cosmochimica Acta, Vol. 69, No. 23, pp. 5403–5412, 2005.
// Part 1: two site protolysis non electrostatic surface complexation.
//----------------------------------------------------------------------------------------
}


//--------  Three surface sites with individual site densities (mol/kg) -------- 
@surfsite(BB_montm, sOH,  2e-3, 1)
@surfsite(BB_montm, w1OH, 4e-2, 1)
@surfsite(BB_montm, w2OH, 4e-2, 1)
//--------------------------------------------------------------


//--------  The site protonation reactions -------- 
@surfspecies(BB_montm, sOH, sOH2+, 1)
@logKsurfreaction(BB_montm_sOH2+,    4.5,  1.0, BB_montm_sOH,  1.0, H+)

@surfspecies(BB_montm, sOH, sO-, 1)
@logKsurfreaction(BB_montm_sO-,     -7.9,  1.0, BB_montm_sOH, -1.0, H+)

@surfspecies(BB_montm, w1OH, w1OH2+, 1)
@logKsurfreaction(BB_montm_w1OH2+,  4.5,  1.0, BB_montm_w1OH,  1.0, H+)

@surfspecies(BB_montm, w1OH, w1O-, 1)
@logKsurfreaction(BB_montm_w1O-,   -7.9,  1.0, BB_montm_w1OH, -1.0, H+)


@surfspecies(BB_montm, w2OH, w2OH2+, 1)
@logKsurfreaction(BB_montm_w2OH2+,  6.0,  1.0, BB_montm_w2OH,  1.0, H+)

@surfspecies(BB_montm, w2OH, w2O-, 1)
@logKsurfreaction(BB_montm_w2O-,  -10.5,  1.0, BB_montm_w2OH, -1.0, H+)
//--------------------------------------------------------------


//-------- The adsorbed EU species --------
@surfspecies(BB_montm, sOH, sO-EU, 1)
@logKsurfreaction(BB_montm_sO-EU, 0.6,  1.0, BB_montm_sOH,  1.0, Eu+3, -1.0, H+)

@surfspecies(BB_montm, sOH, sO-EUOH, 1)
@logKsurfreaction(BB_montm_sO-EUOH,    -6.2,   1.0, BB_montm_sOH,  1.0, Eu+3, -2.0, H+)

@surfspecies(BB_montm, sOH, sO-EU[OH]2, 1)
@logKsurfreaction(BB_montm_sO-EU[OH]2, -14.2,  1.0, BB_montm_sOH,  1.0, Eu+3, -3.0, H+)

@surfspecies(BB_montm, w1OH, w1O-EU, 1)
@logKsurfreaction(BB_montm_w1O-EU,      -1.4,  1.0, BB_montm_w1OH,  1.0, Eu+3, -1.0, H+)
//--------------------------------------------------------------


//--------------------------------------------------------------
// Definition of the Gaines and Thomas surface (CEC part)
//--------------------------------------------------------------
// This model type consists of a single ORCHESTRA phase
@class: adsorptionmodelcode(GT_surface){
   @class: GT_surface(name, parent_phase ,concentration){
      @phase(<name>, <parent_phase>, <concentration>)
   }
}

@class: adsorptionmodeltext(GT_surface){
//----------------------------------------------------------------------------------------
// This class represent an ion exchange model according to the Gaines-Thomas convention.
// Note that for this model the concentrations of surface species are expressed in terms of 
// equivalent or charge fractions.
// So each surface species needs a conversion factor (moles/equivalent) to convert
// surface concentrations in equivalent fractions to moles.
//----------------------------------------------------------------------------------------
}

// Define the components of the GT model
//        modelname, parent particle, Kg/kg, modeltype
@adsmodel(BB_CEC,    part ,           1,      GT_surface)
//--------------------------------------------------------------

@class: adsorptionmodeltext(BB_CEC){
//----------------------------------------------------------------------------------------
// This is an implementation of the (2SPNE SC/CE) two site protolysis non electrostatic surface
// complexation and cation exchange model according to:
// M. H. BRADBURY,1, B. BAEYENS, H. GECKEIS, and TH. RABUNG
// Geochimica et Cosmochimica Acta, Vol. 69, No. 23, pp. 5403–5412, 2005.
// Part 2: the Gaines and Thomas Ion exchange part
//----------------------------------------------------------------------------------------
}

//--------  A single empty surface site with site density (eq/kg) -------- 
// Note that setting the contribution to the site "mass" balance at "0",
// ensures that the site will not exist in free form. 
@surfsite(BB_CEC, X,  0.87,  0)
//--------------------------------------------------------------

//--------------------------------------------------------------
// Now we can define the adsorbed surface species
// Note that for the GT adsorption model is expressed in equivalent fractions.
// This implies that we have to translate equivalent fractions to moles 
// by using the appropriate factor (moles per equivalent) for each surface species
//--------------------------------------------------------------
@surfspecies(BB_CEC, X, X2-Ca, 0.5)
@logKsurfreaction(BB_CEC_X2-Ca,  0.0,  1.0, Ca+2,  2.0, BB_CEC_X)

@surfspecies(BB_CEC, X, X3-Eu, 0.333333)
@logKreaction(BB_CEC_X3-Eu,  1.114000000000     ,  1.0, Eu+3,  3.0, BB_CEC_X)